アーカイブ : 2012年 2月

AIR for AndroidでCapabilitiesで取り出せない端末情報を取り出すクラス

前回の機種判定方法に続いてbuild.propの中にある情報を簡単に取り出せるクラスを作りました。
使い方はCheckAndroidPropクラスのインスタンスを生成してプロパティを参照するだけです。

package
{
	import flash.display.MovieClip;
	import flash.display.StageAlign;
	import flash.display.StageScaleMode;
	import flash.text.TextField;

	public class Main extends MovieClip
	{

		public function Main()
		{
			stage.align = StageAlign.TOP_LEFT;
			stage.scaleMode = StageScaleMode.NO_SCALE;

			var txt:TextField = new TextField();
			txt.width = 480;
			txt.height = 800;
			addChild(txt);
			
			//インスタンスを作成する
			var cap:CheckAndroidProp = new CheckAndroidProp();
			
			//読み取りが成功してたらプロパティを取り出す。
			if (cap.isSuccess) {
				var msg:String = "";
				msg += "この端末のAndroidのバージョンは:" + cap.build_version_release;
				msg += "\nこの端末のビルド番号は:" + cap.build_display_id;
				msg += "\nこの端末のモデル番号は:" + cap.product_model;
				txt.text = msg;
			}
		}
	}
}

CheckAndroidPropクラス

package  
{
	import flash.filesystem.File;
	import flash.filesystem.FileMode;
	import flash.filesystem.FileStream;

	public class CheckAndroidProp 
	{
		private var _isSuccess:Boolean;
		private var _build_id:String = "";
		private var _build_display_id:String = "";
		private var _build_version_incremental:String = "";
		private var _build_version_sdk:String = "";
		private var _build_version_codename:String = "";
		private var _build_version_release:String = "";
		private var _build_date:String = "";
		private var _build_date_utc:String = "";
		private var _build_type:String = "";
		private var _build_user:String = "";
		private var _build_host:String = "";
		private var _build_tags:String = "";
		private var _build_description:String = "";
		private var _build_fingerprint:String = ""; 
		
		
		private var _product_model:String = "";
		private var _product_brand:String = "";
		private var _product_name:String = "";
		private var _product_device:String = "";
		private var _product_board:String = "";
		private var _product_cpu_abi:String = "";
		private var _product_cpu_abi2:String = "";
		private var _product_manufacturer:String = "";
		private var _product_locale_language:String = "";
		private var _product_locale_region:String = "";
		
		
		public function CheckAndroidProp() 
		{
			_isSuccess = init();
		}
		
		private function init():Boolean{
			var flg:Boolean = false;
			
			var file:File = new File("file:///system/build.prop");
			var stream:FileStream = new FileStream();
			
			try {
				stream.open(file, FileMode.READ);
				var str:String = stream.readMultiByte(stream.bytesAvailable, File.systemCharset);
			}catch (err:Error) {
				trace("openerror");
			}finally {
				stream.close();
			}
			if (str) {
				flg = true;
				checkProperty(convertStringToArray(str));
			}
			
			return flg;
		}
		
		private function checkProperty(data:Array):void {
			
			var lg1:int = data.length;
			for (var i:int = 0; i < lg1; i++) {
				if (data[i].indexOf("ro.build.id") == 0) {
					_build_id = data[i].split("=")[1];
				}else if(data[i].indexOf("ro.build.display.id") == 0){
					_build_display_id = data[i].split("=")[1];
				}else if(data[i].indexOf("ro.build.version.incremental") == 0){
					_build_version_incremental = data[i].split("=")[1];
				}else if(data[i].indexOf("ro.build.version.sdk") == 0){
					_build_version_sdk = data[i].split("=")[1];
				}else if(data[i].indexOf("ro.build.version.codename") == 0){
					_build_version_codename = data[i].split("=")[1];
				}else if(data[i].indexOf("ro.build.version.release") == 0){
					_build_version_release = data[i].split("=")[1];
				}else if(data[i].indexOf("ro.build.date=") == 0){
					_build_date = data[i].split("=")[1];
				}else if(data[i].indexOf("ro.build.date.utc") == 0){
					_build_date_utc = data[i].split("=")[1];
				}else if(data[i].indexOf("ro.build.type") == 0){
					_build_type = data[i].split("=")[1];
				}else if(data[i].indexOf("ro.build.user") == 0){
					_build_user = data[i].split("=")[1];
				}else if(data[i].indexOf("ro.build.host") == 0){
					_build_host = data[i].split("=")[1];
				}else if(data[i].indexOf("ro.build.tags") == 0){
					_build_tags = data[i].split("=")[1];
				}else if(data[i].indexOf("ro.build.description") == 0){
					_build_description = data[i].split("=")[1];
				}else if(data[i].indexOf("ro.build.fingerprint") == 0){
					_build_fingerprint = data[i].split("=")[1];
				}else if(data[i].indexOf("ro.product.model") == 0){
					_product_model = data[i].split("=")[1];
				}else if(data[i].indexOf("ro.product.brand") == 0){
					_product_brand = data[i].split("=")[1];
				}else if(data[i].indexOf("ro.product.name") == 0){
					_product_name = data[i].split("=")[1];
				}else if(data[i].indexOf("ro.product.device") == 0){
					_product_device = data[i].split("=")[1];
				}else if(data[i].indexOf("ro.product.board") == 0){
					_product_board = data[i].split("=")[1];
				}else if(data[i].indexOf("ro.product.cpu.abi=") == 0){
					_product_cpu_abi = data[i].split("=")[1];
				}else if(data[i].indexOf("ro.product.cpu.abi2") == 0){
					_product_cpu_abi2 = data[i].split("=")[1];
				}else if(data[i].indexOf("ro.product.manufacturer") == 0){
					_product_manufacturer = data[i].split("=")[1];
				}else if(data[i].indexOf("ro.product.locale.language") == 0){
					_product_locale_language = data[i].split("=")[1];
				}else if(data[i].indexOf("ro.product.locale.region") == 0){
					_product_locale_region = data[i].split("=")[1];
				}
			}
		}
		
		//テキストデータの整形
		public function convertStringToArray(rawdata:String):Array{
			rawdata = (rawdata.split("\r\n")).join("\n");
			rawdata = (rawdata.split("\r")).join("\n");
			var data:Array = new Array();
			var tmp:Array = rawdata.split("\n");
			return tmp;
		}
		
		public function get product_locale_region():String 
		{
			return _product_locale_region;
		}
		
		public function get product_locale_language():String 
		{
			return _product_locale_language;
		}
		
		public function get product_manufacturer():String 
		{
			return _product_manufacturer;
		}
		
		public function get product_cpu_abi2():String 
		{
			return _product_cpu_abi2;
		}
		
		public function get product_cpu_abi():String 
		{
			return _product_cpu_abi;
		}
		
		public function get product_board():String 
		{
			return _product_board;
		}
		
		public function get product_device():String 
		{
			return _product_device;
		}
		
		public function get product_name():String 
		{
			return _product_name;
		}
		
		public function get product_brand():String 
		{
			return _product_brand;
		}
		
		public function get product_model():String 
		{
			return _product_model;
		}
		
		public function get build_tags():String 
		{
			return _build_tags;
		}
		
		public function get build_host():String 
		{
			return _build_host;
		}
		
		public function get build_user():String 
		{
			return _build_user;
		}
		
		public function get build_type():String 
		{
			return _build_type;
		}
		
		public function get build_date():String 
		{
			return _build_date;
		}
		
		public function get build_version_release():String 
		{
			return _build_version_release;
		}
		
		public function get build_version_codename():String 
		{
			return _build_version_codename;
		}
		
		public function get build_version_sdk():String 
		{
			return _build_version_sdk;
		}
		
		public function get build_version_incremental():String 
		{
			return _build_version_incremental;
		}
		
		public function get build_id():String 
		{
			return _build_id;
		}
		
		public function get build_display_id():String 
		{
			return _build_display_id;
		}
		
		public function get build_date_utc():String 
		{
			return _build_date_utc;
		}
		
		public function get isSuccess():Boolean 
		{
			return _isSuccess;
		}
		
		public function get build_description():String 
		{
			return _build_description;
		}
		
		public function get build_fingerprint():String 
		{
			return _build_fingerprint;
		}
	}
}

使用、改変は自由にどうぞ。利用の際の損害については補償しませんのであしからず!

AIR fo Androidでの機種判定

今日のfxugでGREEの方から教えて頂きました。
URLLoaderで端末の固定パス上にあるbuild.propというファイルを見に行くそうです。
build.propと呼ばれるファイルの詳細はこちらのブログの方が解説されています。

package
{
	import flash.display.Sprite;
	import flash.display.StageAlign;
	import flash.display.StageScaleMode;
	import flash.events.Event;
	import flash.net.URLLoader;
	import flash.net.URLLoaderDataFormat;
	import flash.net.URLRequest;
	import flash.text.TextField;

	public class ProductSample extends Sprite
	{
		private var txtf:TextField;

		public function ProductSample()
		{
			stage.scaleMode = StageScaleMode.NO_SCALE;
			stage.align = StageAlign.TOP_LEFT;

			txtf = new TextField();
			txtf.width = 480;
			txtf.height = 800;

			addChild(txtf);

			var loader:URLLoader = new URLLoader();
			loader.dataFormat = URLLoaderDataFormat.TEXT;
			var request:URLRequest = new URLRequest("file:///system/build.prop");
			loader.addEventListener(Event.COMPLETE,onComp);
			loader.load(request);

		}

		protected function onComp(event:Event):void
		{
			txtf.text = event.target.data as String;
		}
	}
}

実行結果は下のような感じになるのでこれを改行でsplitして必要な当該項目を抜き出せば判定可能といった感じでしょうか。
またsqlliteで端末別に機能表とかも合わせて持っておけば個別の処理などが可能になってきそうですね。

 

<追記2013.8.13>

機種判定をやってくれる便利なライブラリがでました。
https://code.google.com/p/maashaack-library-ax/source/browse/trunk/src/air/desktop/DeviceModel.as#126

異なるデバイス間の通信の種類 Flash/AIR

以前はPCオンリーの環境でしたが、スマートフォンやタブレットなどが台頭してきたので異なるデバイス上での通信などが必要になるケースが有ると思います。自分にもそういう案件が降ってきたのでメモ程度に通信タイプをまとめてみました。

※曖昧なので誤りがあれば指摘ください!

  1. 同じLAN内にあるデバイス間の通信P2P
  2. P2P(要サーバー)
  3. FMS(FlashMediaServer)
  4. XMLSocketによる通信
  5. webSocketによる通信

同じLAN内にあるデバイス間の通信P2P

一切サーバーを経由させずにLAN内のデバイス間通信ができます。ただし、通信がLAN環境に依存します。※PCとスマホ間を通信する場合、スマホが3Gで接続しちゃうとNG

参考資料:
HIMCOさんの解説ページ
GroupSpecifier クラス解説

P2P

とても自由度が高い半面、デバイスとデバイスをつなぐ時のみサーバーが必要。つないだ後はP2Pで通信。サーバー側のサービスは有料のLCCSCirrusなどがある。通信はクライアント同士なのでFMSのようなサーバー配信タイプと違って通信コストがとても安く抑えられます。

※LCCSにはデベロッパー用の無料アカウントもあったり、チャットやサンプルも充実してたりします。
※Cirrusはまだβっぽいです。

参考資料:
LCCSでP2Pマルチキャストのビデオ配信を行うサンプル
Cirrusの仕組みと接続サンプル
上条さんによるRTMP/RTMFP解説

FMS(Flash Media Server)

昔からあるFlash Media Serverです。映像配信がメインのイメージがありますが、SharedObjectクラスをつかって双方向通信もできます。ただ、FMSはどちらかというと映像配信向けのソリューションなので双方向通信だけで見た場合は上記のP2PやXMLsocket通信のほうが実装しやすいかと思います。最近では安価な従量課金タイプのAdobe Flash Media Server on Amazon Web Servicesなどもリリースされています。さらに映像配信もP2Pでできたりするので安定した配信をしたい場合はFMS選択となる感じでしょうか。こちらはFMS側にサンプルが充実しているので資料は割愛。

XMLSocket通信

これもFlash ver5あたりから存在するXMLSocketで双方向通信を実現することができます。通信はクライアント←→サーバ間で行うため常時サーバーが必須になります。ただこのサーバーがAdobeが用意していないので自前サーバーを用意して、サーバー側のプログラムも作成しないといけないという敷居の高さが存在します。大人数、大容量の通信は向いてません。

参考資料:
XMLsocket接続サンプル(cantenaさんのブログ)
XMLsocketサーバ(ダウンロードたけし(寅年)の日記)
XMLsocketサーバ(バスキュールさんのFaces)

websocketによる通信

なんでFlashにわざわざXMLSocketがあるのにHTML5のwebsocketAPIを使うのか?なんて疑問に思うかもしれませんがFlash←→HTML5でつくったサイトというケースもあるので一応書きます。まずこれを実現するためにはHTML5対応ブラウザという壁を乗り越える必要があります。またjsを経由するのでjs←→flash間のやり取りを行う必要があります。さらにサーバーサイドのプログラムも自前で準備します。

(追記)2/22 GREEの中の方がwebsocket Actionscript Clientを作ってるそうです。GREEさんの場合はnode.jsをメインに使ってる関係でwebsocketを採用したそうです。AIRの場合はXMLSocketやP2Pがあるのでパフォーマンス重視の場合はこの選択肢は選ばないほうがいいかもしれません。

参考資料:
websocket+Flash+js(gimiteさんのブログ)

Google Weather API for Flash

Google Weather API を最近知ったのでFlashで利用できるライブラリを作ってみました。

Google Weather APIは指定した地点における現在の情報と四日間の天気予報を提供してくれるAPIです。

Google Weather APIは非公式、非商用、ガジェットのみとあったので利用される際は注意お願いします。

このAPIは引数に地点名を入力するモードと緯度経度を入力して近くの地点の情報を取得するモードがあります。

ここでは緯度経度を用いて天気予報を取得しています。

package
{
	import flash.events.Event;
	import flash.events.EventDispatcher;
	import flash.events.IEventDispatcher;
	import flash.events.IOErrorEvent;
	import flash.net.URLLoader;
	import flash.net.URLRequest;

	public class GoogleWeatherApi extends EventDispatcher
	{
		public static const GOOGLE_API_URL:String="http://www.google.com/ig/api?weather=,,,";

		private var loader:URLLoader;
		public var xml:XML;
		var urlrequest:URLRequest;

		public function GoogleWeatherApi(latitude:int,longitude:int,language:String="ja")
		{

			var address:String = GOOGLE_API_URL+latitude.toString()+","+longitude.toString()+"&hl="+language;
			urlrequest = new URLRequest(address);
			loader = new URLLoader();
			loader.addEventListener(Event.COMPLETE,onDataComp);
			loader.addEventListener(IOErrorEvent.IO_ERROR,onError);
		}
		public function load():void {

			loader.load(urlrequest);
		}

		private function onDataComp(event:Event):void
		{
			loader.removeEventListener(Event.COMPLETE,onDataComp);
			loader.removeEventListener(IOErrorEvent.IO_ERROR,onError);

			xml = new XML(event.target.data);
			dispatchEvent(new Event(Event.COMPLETE));
		}
		private function onError(event:IOErrorEvent):void
		{
			loader.removeEventListener(Event.COMPLETE,onDataComp);
			loader.removeEventListener(IOErrorEvent.IO_ERROR,onError);
			dispatchEvent(new IOErrorEvent(IOErrorEvent.IO_ERROR));
		}

		//現在のコンディションを取得する
		public function getCurrentCondition():Object {

			//現在のコンディション
			var objCurrent:Object = new Object();
				//天気
				objCurrent.condition = xml.weather.current_conditions.condition.@data;
				//気温:華氏(F)
				objCurrent.temp_f = xml.weather.current_conditions.temp_f.@data;
				//気温:摂氏(℃)
				objCurrent.temp_c = xml.weather.current_conditions.temp_c.@data;
				//湿度%
				objCurrent.humidity = xml.weather.current_conditions.humidity.@data;
				//お天気アイコン画像へのパス
				objCurrent.icon = xml.weather.current_conditions.icon.@data;
				//風向きと風速
				objCurrent.wind_condition = xml.weather.current_conditions.wind_condition.@data;

			return objCurrent;
		}

		//天気予報を取得する
		public function getForecast():Array {
			var ar:Array = new Array();

			//本日から四日間の予報
			for (var i:int = 0; i < xml.weather.forecast_conditions.length(); i++) {
				var obj:Object = new Object();
				//曜日
				obj.day_of_week = xml.weather.forecast_conditions[i].day_of_week.@data;
				//最低気温
				obj.low = xml.weather.forecast_conditions[i].low.@data;
				//最高気温
				obj.high = xml.weather.forecast_conditions[i].high.@data;
				//アイコン画像
				obj.icon = xml.weather.forecast_conditions[i].icon.@data;
				//天気予報
				obj.condition = xml.weather.forecast_conditions[i].condition.@data;
				ar.push(obj);
			}
			return ar;
		}
	}
}

使い方は

package  
{
	import flash.display.MovieClip;
	import flash.events.Event;
	import flash.system.System;

	public class Main extends MovieClip 
	{
		
		public function Main() 
		{
			
			//日本語で取得する場合はSHIFT-JISできます。
			System.useCodePage = true;
			
			//緯度と経度に10の6乗かけて整数にした値をGoogleWeatherAPIクラスのインスタンスに放り込む。
			var gwa:GoogleWeatherApi = new GoogleWeatherApi(35680900, 139767200);
			gwa.addEventListener(Event.COMPLETE, onComp);
			gwa.load();
		}
		
		//データ取得時
		private function onComp(e:Event):void 
		{
			var gwa:GoogleWeatherApi = e.target as GoogleWeatherApi;
			
			//現在の状態を出力します。
			trace("現在の情報---------------------------");
			var currentdata:Object = gwa.getCurrentCondition();
			for (var paramName:String in currentdata){
				trace(paramName,currentdata[paramName]);
			}
			
			trace("\n\n\n天気予報---------------------------");
			
			
			var forecastdata:Array = gwa.getForecast();

			for (var i:int = 0; i < forecastdata.length; i++) {
				trace("\nnextday------------")
				for (var cparamName:String in forecastdata[i]){
					trace(cparamName,forecastdata[i][cparamName]);
				}
			}
		}
	}
}

改造、コピペ自由にどうぞ。